Wavetable export issue

[d.healey]

@Lindon Should the wavetables be embedded in the plugin or are they in a separate .dat file?

[Lindon]

@d-healey they should be embeded no?

[d.healey]

@Lindon I have no idea, I'm just making guesses.

[Matt_SF]

@Lindon They are not embedded into the plugin, and not installed automatically.
The *.hwt files must be copied manually into appData/Audio files/

[A Former User]

Is the WaveTable synth production-ready now?

[Lindon]

@Matt_SF said in Wavetable export issue:

@Lindon They are not embedded into the plugin, and not installed automatically.
The *.hwt files must be copied manually into appData/Audio files/

thanks.

Sigh - but that's not good news - its looking more and more like I have to build my own installer in HISE....meanwhile I need to work out how to get inno and WhiteBox to install these in the correct place - inno I think should be pretty easy....anyone got any clues for WhiteBox Packages?

[Matt_SF]

@Lindon I'll be at home soon and I'll post both scripts I'm using to install the files

[Lindon]

@Matt_SF cool thanks.

[Matt_SF]

@Lindon On MacOs, setup Packages like this :

And use this post script :

#!/bin/sh
# ensure plugin directory actually exists
sudo -u $USER mkdir -p $HOME/Library/Application\ Support/Company\ Name/Product\ Name/

# move and sync files from temporary payload to real plugin directory
/usr/bin/rsync -avurpE --remove-source-files /Library/Application\ Support/Company\ Name/Product\ Name/ $HOME/Library/Application\ Support/Company\ Name/Product\ Name/

# ensure permissions are recursively set to current user for plugin directory
sudo find $HOME/Library/Application\ Support/Company\ Name/ -type d -user root -exec sudo chown -R $USER: {} +

# remove temporary folder
find /Library/Application\ Support/Company\ Name/ -type d -empty -delete

exit 0

Basically, the installer will copy the files in the 'HD/Library/etc...' folder and the script will move them to the user appData folder.

This is not my work : the original script was posted by @dustbro, in this thread.

[Matt_SF]

@Lindon On windows I'm using this script :

[Setup]

#define AppName "Product Name"
#define AppVersion "1.0.0"
#define DevDir "Company Name"
PrivilegesRequired=admin
AppName={#AppName}
AppVersion={#AppVersion}

DefaultDirName={pf}\{#DevDir}\{#AppName}
DefaultGroupName={#AppName}
Compression=lzma2
SolidCompression=yes
OutputDir=.\installerbuild
ArchitecturesInstallIn64BitMode=x64
OutputBaseFilename={#AppName} Setup

; BANNER

DisableWelcomePage=no
DisableDirPage=yes
DisableProgramGroupPage=yes

SetupLogging=yes
ChangesAssociations=no

[Types]
Name: "full"; Description: "Full installation"

[Dirs]
Name: "{app}\"; Permissions: users-modify powerusers-modify admins-modify system-modify
Name: "{userappdata}\{#DevDir}\{#AppName}\"; Permissions: users-modify powerusers-modify admins-modify system-modify
                    
[Components]
Name: "vst3_64"; Description: "{#AppName} {#AppVersion} VST3 Plugin"; Types: full; Check: Is64BitInstallMode; 
Name: "AudioFiles"; Description: "{#AppName} AudioFiles"; Types: full;

[Files]

; VST
Source: "Binaries\Compiled\VST3\{#AppName}.vst3"; DestDir: "{code:GetVST3Dir_64}\{#DevDir}"; Flags: ignoreversion; Components: vst3_64; Check: Is64BitInstallMode

; SAMPLES
Source: "AudioFiles\*"; DestDir: "{userappdata}\{#DevDir}\{#AppName}\AudioFiles"; Check: Is64BitInstallMode
; Use : Flags: recursesubdirs;   if the AudioFiles folder contains other folders and files you want to include in the installer

[Icons]

Name: "{group}\Uninstall {#AppName}"; Filename: "{app}\Uninstall{#AppName}.exe"    

[Code]
var
  OkToCopyLog : Boolean;
  VST3DirPage_64: TInputDirWizardPage;
  AppDataFolder: String;

procedure InitializeWizard;

begin

  if IsWin64 then begin
    VST3DirPage_64 := CreateInputDirPage(wpSelectDir,
    'Confirm 64-Bit VST2 Plugin Directory', '',
    'Select the folder in which setup should install Le Skank VST3 plugin,  then click Next.',
    False, '');
    VST3DirPage_64.Add('');
    VST3DirPage_64.Values[0] := ExpandConstant('{commoncf64}\VST3\');
    end;
end;

function GetVST3Dir_64(Param: String): String;
begin
  Result := VST3DirPage_64.Values[0]
end;

procedure CurStepChanged(CurStep: TSetupStep);

begin
  if CurStep = ssDone then
    OkToCopyLog := True;
end;

procedure DeinitializeSetup();

begin
  if OkToCopyLog then
    FileCopy (ExpandConstant ('{log}'), ExpandConstant ('{app}\InstallationLogFile.log'), FALSE);
  RestartReplace (ExpandConstant ('{log}'), '');
end;

[UninstallDelete]
Type: files; Name: "{app}\InstallationLogFile.log"

(Note that I'm only offering VST3 plugins).

It works fine but I'm not an expert at Inno Setup, so anyone is welcome to correct me :)

Inspired by the original script by @orange, found in this thread.

[Lindon]

@Matt_SF thanks Mat - I will take a run at it...