Reply to Aligned Text with the LAF Arc Knob on Wed, 29 Jun 2022 21:50:26 GMT

Fortune — Wed, 29 Jun 2022 21:50:26 GMT

@Christoph-Hart Fantastic! Thank you so much!

Reply to Aligned Text with the LAF Arc Knob on Wed, 29 Jun 2022 21:20:34 GMT

Christoph Hart — Wed, 29 Jun 2022 21:20:34 GMT

@Fortune I'm using a bunch of helper functions that mimic the juce::Rectangle methods and allow super easy rectangle layout:

namespace Rect
{
	inline function reduced(area, amount)
	{
		return [ area[0] + amount, 
				 area[1] + amount, 
				 area[2] - 2 * amount, 
				 area[3] - 2 * amount];
	}
	
	inline function copy(area)
	{
		return [ area[0], area[1], area[2], area[3]];
	}
	
	inline function contains(area, point)
	{
		return point[0] >= area[0] && 
			   point[0] < area[0] + area[2] &&
			   point[1] >= area[1] && 
			   point[1] < area[1] + area[3];
	}
	
	inline function withSizeKeepingCentre(area, width, height)
	{
		return [ area[0] + (area[2] - width) / 2, 
				 area[1] + (area[3] - height) / 2, 
				 width, 
				 height];
	}
	
	inline function removeFromLeft(area, amount)
	{
		area[0] += amount;
		area[2] -= amount;
		return [area[0] - amount, area[1], amount, area[3]];
	}
	
	inline function removeFromRight(area, amount)
	{
		area[2] -= amount;
		return [area[0] + area[2], area[1], amount, area[3]];
	}
	
	inline function removeFromTop(area, amount)
	{
		area[1] += amount;
		area[3] -= amount;
		return [area[0], area[1] - amount, area[2], amount];
	}
	
	inline function scale(area, scaleFactor)
	{
		local newArea = [];
		newArea.reserve(4);
		
		for(a in area)
			newArea.push(a * scaleFactor);
			
		return newArea;
	}
	
	inline function removeFromBottom(area, amount)
	{
		
	

		area[3] -= amount;

		return [area[0], area[1] + area[3], area[2], amount];
	
	}
	
	inline function translated(area, xDelta, yDelta)
	{
		return [area[0] + xDelta, area[1] + yDelta, area[2], area[3]];
	}
}

Those should get you started.

Reply to Aligned Text with the LAF Arc Knob on Wed, 29 Jun 2022 21:07:13 GMT

Fortune — Wed, 29 Jun 2022 21:07:13 GMT

@Christoph-Hart Thanks.

I will try to center all path bounds but I think it is beyond my knowledge :/

Reply to Aligned Text with the LAF Arc Knob on Wed, 29 Jun 2022 20:54:54 GMT

Christoph Hart — Wed, 29 Jun 2022 20:54:54 GMT

@Fortune Your knob is completely left aligned, this will not work (Amount is wider than the knob). You need to center all path bounds, then you can use centredTop as alignment.